/*
 * Licensed to the Apache Software Foundation (ASF) under one or more
 * contributor license agreements.  See the NOTICE file distributed with
 * this work for additional information regarding copyright ownership.
 * The ASF licenses this file to You under the Apache License, Version 2.0
 * (the "License"); you may not use this file except in compliance with
 * the License.  You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
module hunt.pool.impl.GenericObjectPool;

import hunt.pool.impl.AbandonedConfig;
import hunt.pool.impl.BaseGenericObjectPool;
import hunt.pool.impl.BaseObjectPoolConfig;
import hunt.pool.impl.DefaultPooledObject;
import hunt.pool.impl.DefaultPooledObjectInfo;
import hunt.pool.impl.EvictionConfig;
import hunt.pool.impl.EvictionPolicy;
import hunt.pool.impl.GenericObjectPoolConfig;
import hunt.pool.impl.GenericObjectPoolMXBean;
import hunt.pool.impl.LinkedBlockingDeque;


import hunt.pool.ObjectPool;
import hunt.pool.PoolUtils;
import hunt.pool.PooledObject;
import hunt.pool.PooledObjectFactory;
import hunt.pool.PooledObjectState;
import hunt.pool.SwallowedExceptionListener;
import hunt.pool.TrackedUse;
import hunt.pool.UsageTracking;

import hunt.Boolean;
import hunt.collection;
import hunt.concurrency.atomic.AtomicHelper;
import hunt.concurrency.thread;
import hunt.concurrency.SimpleObjectLock;
import hunt.Exceptions;
import hunt.logging.ConsoleLogger;
import hunt.util.StringBuilder;
import hunt.util.DateTime;

import core.time;
import std.algorithm;
import std.math;

/**
 * A configurable {@link ObjectPool} implementation.
 * <p>
 * When coupled with the appropriate {@link PooledObjectFactory},
 * <code>GenericObjectPool</code> provides robust pooling functionality for
 * arbitrary objects.</p>
 * <p>
 * Optionally, one may configure the pool to examine and possibly evict objects
 * as they sit idle in the pool and to ensure that a minimum number of idle
 * objects are available. This is performed by an "idle object eviction" thread,
 * which runs asynchronously. Caution should be used when configuring this
 * optional feature. Eviction runs contend with client threads for access to
 * objects in the pool, so if they run too frequently performance issues may
 * result.</p>
 * <p>
 * The pool can also be configured to detect and remove "abandoned" objects,
 * i.e. objects that have been checked out of the pool but neither used nor
 * returned before the configured
 * {@link AbandonedConfig#getRemoveAbandonedTimeout() removeAbandonedTimeout}.
 * Abandoned object removal can be configured to happen when
 * <code>borrowObject</code> is invoked and the pool is close to starvation, or
 * it can be executed by the idle object evictor, or both. If pooled objects
 * implement the {@link TrackedUse} interface, their last use will be queried
 * using the <code>getLastUsed</code> method on that interface; otherwise
 * abandonment is determined by how long an object has been checked out from
 * the pool.</p>
 * <p>
 * Implementation note: To prevent possible deadlocks, care has been taken to
 * ensure that no call to a factory method will occur within a synchronization
 * block. See POOL-125 and DBCP-44 for more information.</p>
 * <p>
 * This class is intended to be thread-safe.</p>
 *
 * @see GenericKeyedObjectPool
 *
 * @param <T> Type of element pooled in this pool.
 *
 */
class GenericObjectPool(T) : BaseGenericObjectPool,
        ObjectPool!(T),  UsageTracking!(T) { // GenericObjectPoolMXBean,

    /**
     * Creates a new <code>GenericObjectPool</code> using defaults from
     * {@link GenericObjectPoolConfig}.
     *
     * @param factory The object factory to be used to create object instances
     *                used by this pool
     */
    this(PooledObjectFactory!(T) factory) {
        this(factory, new GenericObjectPoolConfig());
    }

    /**
     * Creates a new <code>GenericObjectPool</code> using a specific
     * configuration.
     *
     * @param factory   The object factory to be used to create object instances
     *                  used by this pool
     * @param config    The configuration to use for this pool instance. The
     *                  configuration is used by value. Subsequent changes to
     *                  the configuration object will not be reflected in the
     *                  pool.
     */
    this(PooledObjectFactory!(T) factory,
            GenericObjectPoolConfig config) {

        makeObjectCountLock = new Object();
        super(config, ONAME_BASE, config.getJmxNamePrefix());
        // allObjects = new ConcurrentHashMap<>();
        allObjects = new HashMap!(IdentityWrapper!(T), PooledObject!(T))();

        if (factory is null) {
            // jmxUnregister(); // tidy up
            throw new IllegalArgumentException("factory may not be null");
        }
        this.factory = factory;

        idleObjects = new LinkedBlockingDeque!(IPooledObject)(config.getFairness());

        setConfig(config);
    }

    /**
     * Creates a new <code>GenericObjectPool</code> that tracks and destroys
     * objects that are checked out, but never returned to the pool.
     *
     * @param factory   The object factory to be used to create object instances
     *                  used by this pool
     * @param config    The base pool configuration to use for this pool instance.
     *                  The configuration is used by value. Subsequent changes to
     *                  the configuration object will not be reflected in the
     *                  pool.
     * @param abandonedConfig  Configuration for abandoned object identification
     *                         and removal.  The configuration is used by value.
     */
    this(PooledObjectFactory!(T) factory,
            GenericObjectPoolConfig config, AbandonedConfig abandonedConfig) {
        this(factory, config);
        setAbandonedConfig(abandonedConfig);
    }

    /**
     * Returns the cap on the number of "idle" instances in the pool. If maxIdle
     * is set too low on heavily loaded systems it is possible you will see
     * objects being destroyed and almost immediately new objects being created.
     * This is a result of the active threads momentarily returning objects
     * faster than they are requesting them, causing the number of idle
     * objects to rise above maxIdle. The best value for maxIdle for heavily
     * loaded system will vary but the default is a good starting point.
     *
     * @return the maximum number of "idle" instances that can be held in the
     *         pool or a negative value if there is no limit
     *
     * @see #setMaxIdle
     */
    // override
    int getMaxIdle() {
        return maxIdle;
    }

    /**
     * Returns the cap on the number of "idle" instances in the pool. If maxIdle
     * is set too low on heavily loaded systems it is possible you will see
     * objects being destroyed and almost immediately new objects being created.
     * This is a result of the active threads momentarily returning objects
     * faster than they are requesting them, causing the number of idle
     * objects to rise above maxIdle. The best value for maxIdle for heavily
     * loaded system will vary but the default is a good starting point.
     *
     * @param maxIdle
     *            The cap on the number of "idle" instances in the pool. Use a
     *            negative value to indicate an unlimited number of idle
     *            instances
     *
     * @see #getMaxIdle
     */
    void setMaxIdle(int maxIdle) {
        this.maxIdle = maxIdle;
    }

    /**
     * Sets the target for the minimum number of idle objects to maintain in
     * the pool. This setting only has an effect if it is positive and
     * {@link #getTimeBetweenEvictionRunsMillis()} is greater than zero. If this
     * is the case, an attempt is made to ensure that the pool has the required
     * minimum number of instances during idle object eviction runs.
     * <p>
     * If the configured value of minIdle is greater than the configured value
     * for maxIdle then the value of maxIdle will be used instead.
     * </p>
     *
     * @param minIdle
     *            The minimum number of objects.
     *
     * @see #getMinIdle()
     * @see #getMaxIdle()
     * @see #getTimeBetweenEvictionRunsMillis()
     */
    void setMinIdle(int minIdle) {
        this.minIdle = minIdle;
    }

    /**
     * Returns the target for the minimum number of idle objects to maintain in
     * the pool. This setting only has an effect if it is positive and
     * {@link #getTimeBetweenEvictionRunsMillis()} is greater than zero. If this
     * is the case, an attempt is made to ensure that the pool has the required
     * minimum number of instances during idle object eviction runs.
     * <p>
     * If the configured value of minIdle is greater than the configured value
     * for maxIdle then the value of maxIdle will be used instead.
     * </p>
     *
     * @return The minimum number of objects.
     *
     * @see #setMinIdle(int)
     * @see #setMaxIdle(int)
     * @see #setTimeBetweenEvictionRunsMillis(long)
     */
    // override
    int getMinIdle() {
        int maxIdleSave = getMaxIdle();
        if (this.minIdle > maxIdleSave) {
            return maxIdleSave;
        }
        return minIdle;
    }

    /**
     * Gets whether or not abandoned object removal is configured for this pool.
     *
     * @return true if this pool is configured to detect and remove
     * abandoned objects
     */
    // override
    bool isAbandonedConfig() {
        return abandonedConfig !is null;
    }

    /**
     * Gets whether this pool identifies and logs any abandoned objects.
     *
     * @return {@code true} if abandoned object removal is configured for this
     *         pool and removal events are to be logged otherwise {@code false}
     *
     * @see AbandonedConfig#getLogAbandoned()
     */
    // override
    bool getLogAbandoned() {
        AbandonedConfig ac = this.abandonedConfig;
        return ac !is null && ac.getLogAbandoned();
    }

    /**
     * Gets whether a check is made for abandoned objects when an object is borrowed
     * from this pool.
     *
     * @return {@code true} if abandoned object removal is configured to be
     *         activated by borrowObject otherwise {@code false}
     *
     * @see AbandonedConfig#getRemoveAbandonedOnBorrow()
     */
    // override
    bool getRemoveAbandonedOnBorrow() {
        AbandonedConfig ac = this.abandonedConfig;
        return ac !is null && ac.getRemoveAbandonedOnBorrow();
    }

    /**
     * Gets whether a check is made for abandoned objects when the evictor runs.
     *
     * @return {@code true} if abandoned object removal is configured to be
     *         activated when the evictor runs otherwise {@code false}
     *
     * @see AbandonedConfig#getRemoveAbandonedOnMaintenance()
     */
    // override
    bool getRemoveAbandonedOnMaintenance() {
        AbandonedConfig ac = this.abandonedConfig;
        return ac !is null && ac.getRemoveAbandonedOnMaintenance();
    }

    /**
     * Obtains the timeout before which an object will be considered to be
     * abandoned by this pool.
     *
     * @return The abandoned object timeout in seconds if abandoned object
     *         removal is configured for this pool; int.max otherwise.
     *
     * @see AbandonedConfig#getRemoveAbandonedTimeout()
     */
    // override
    int getRemoveAbandonedTimeout() {
        AbandonedConfig ac = this.abandonedConfig;
        return ac !is null ? ac.getRemoveAbandonedTimeout() : int.max;
    }


    /**
     * Sets the base pool configuration.
     *
     * @param conf the new configuration to use. This is used by value.
     *
     * @see GenericObjectPoolConfig
     */
    void setConfig(GenericObjectPoolConfig conf) {
        super.setConfig(conf);
        setMaxIdle(conf.getMaxIdle());
        setMinIdle(conf.getMinIdle());
        setMaxTotal(conf.getMaxTotal());
    }

    alias setConfig = BaseGenericObjectPool.setConfig;

    /**
     * Sets the abandoned object removal configuration.
     *
     * @param abandonedConfig the new configuration to use. This is used by value.
     *
     * @see AbandonedConfig
     */
    void setAbandonedConfig(AbandonedConfig abandonedConfig) {
        if (abandonedConfig is null) {
            this.abandonedConfig = null;
        } else {
            this.abandonedConfig = new AbandonedConfig();
            this.abandonedConfig.setLogAbandoned(abandonedConfig.getLogAbandoned());
            // this.abandonedConfig.setLogWriter(abandonedConfig.getLogWriter());
            this.abandonedConfig.setRemoveAbandonedOnBorrow(abandonedConfig.getRemoveAbandonedOnBorrow());
            this.abandonedConfig.setRemoveAbandonedOnMaintenance(abandonedConfig.getRemoveAbandonedOnMaintenance());
            this.abandonedConfig.setRemoveAbandonedTimeout(abandonedConfig.getRemoveAbandonedTimeout());
            this.abandonedConfig.setUseUsageTracking(abandonedConfig.getUseUsageTracking());
            this.abandonedConfig.setRequireFullStackTrace(abandonedConfig.getRequireFullStackTrace());
        }
    }

    /**
     * Obtains a reference to the factory used to create, destroy and validate
     * the objects used by this pool.
     *
     * @return the factory
     */
    PooledObjectFactory!(T) getFactory() {
        return factory;
    }

    /**
     * Equivalent to <code>{@link #borrowObject(long)
     * borrowObject}({@link #getMaxWaitMillis()})</code>.
     * <p>
     * {@inheritDoc}
     * </p>
     */
    // override
    T borrowObject(){
        return borrowObject(getMaxWaitMillis());
    }

    /**
     * Borrows an object from the pool using the specific waiting time which only
     * applies if {@link #getBlockWhenExhausted()} is true.
     * <p>
     * If there is one or more idle instance available in the pool, then an
     * idle instance will be selected based on the value of {@link #getLifo()},
     * activated and returned. If activation fails, or {@link #getTestOnBorrow()
     * testOnBorrow} is set to <code>true</code> and validation fails, the
     * instance is destroyed and the next available instance is examined. This
     * continues until either a valid instance is returned or there are no more
     * idle instances available.
     * </p>
     * <p>
     * If there are no idle instances available in the pool, behavior depends on
     * the {@link #getMaxTotal() maxTotal}, (if applicable)
     * {@link #getBlockWhenExhausted()} and the value passed in to the
     * <code>borrowMaxWaitMillis</code> parameter. If the number of instances
     * checked out from the pool is less than <code>maxTotal,</code> a new
     * instance is created, activated and (if applicable) validated and returned
     * to the caller. If validation fails, a <code>NoSuchElementException</code>
     * is thrown.
     * </p>
     * <p>
     * If the pool is exhausted (no available idle instances and no capacity to
     * create new ones), this method will either block (if
     * {@link #getBlockWhenExhausted()} is true) or throw a
     * <code>NoSuchElementException</code> (if
     * {@link #getBlockWhenExhausted()} is false). The length of time that this
     * method will block when {@link #getBlockWhenExhausted()} is true is
     * determined by the value passed in to the <code>borrowMaxWaitMillis</code>
     * parameter.
     * </p>
     * <p>
     * When the pool is exhausted, multiple calling threads may be
     * simultaneously blocked waiting for instances to become available. A
     * "fairness" algorithm has been implemented to ensure that threads receive
     * available instances in request arrival order.
     * </p>
     *
     * @param borrowMaxWaitMillis The time to wait in milliseconds for an object
     *                            to become available
     *
     * @return object instance from the pool
     *
     * @throws NoSuchElementException if an instance cannot be returned
     *
     * @throws Exception if an object instance cannot be returned due to an
     *                   error
     */
    T borrowObject(long borrowMaxWaitMillis) {
        version(HUNT_DEBUG) {
            import core.thread;
            tracef("%s, Total: %d, Active: %d, Idle: %d, Waiters: %d, MaxWaitMillis: %d, Threads: %d", 
                typeid(T), getMaxTotal(), getNumActive(), getNumIdle(), getNumWaiters(), 
                borrowMaxWaitMillis, Thread.getAll().length);

            scope(exit) {
                infof("Total: %d, Active: %d, Idle: %d, Waiters: %d, Threads: %d", 
                    getMaxTotal(), getNumActive(), getNumIdle(), getNumWaiters(), Thread.getAll().length);
            }                
        }

        assertOpen();

        AbandonedConfig ac = this.abandonedConfig;
        if (ac !is null && ac.getRemoveAbandonedOnBorrow() &&
                (getNumIdle() < 2) && (getNumActive() > getMaxTotal() - 3) ) {
            removeAbandoned(ac);
        }

        IPooledObject p = null;

        // Get local copy of current config so it is consistent for entire
        // method execution
        bool blockWhenExhausted = getBlockWhenExhausted();

        bool isCreated;
        long waitTime = DateTime.currentTimeMillis();

        while (p is null) {
            isCreated = false;
            p = idleObjects.pollFirst();
            if (p is null) {
                p = create();
                if (p !is null) {
                    isCreated = true;
                }
            }

            if (blockWhenExhausted) {
                if (p is null) {
                    if (borrowMaxWaitMillis < 0) {
                        p = idleObjects.takeFirst();
                    } else {
                        p = idleObjects.pollFirst(borrowMaxWaitMillis.msecs);
                    }
                }

                if (p is null) {
                    throw new NoSuchElementException("Timeout waiting for idle object");
                }
            } else {
                if (p is null) {
                    throw new NoSuchElementException("Pool exhausted");
                }
            }

            if (!p.allocate()) {
                p = null;
            }

            if (p !is null) {
                try {
                    factory.activateObject(p);
                } catch (Exception e) {
                    try {
                        destroy(p);
                    } catch (Exception e1) {
                        // Ignore - activation failure is more important
                    }
                    p = null;
                    if (isCreated) {
                        NoSuchElementException nsee = new NoSuchElementException(
                                "Unable to activate object", e);
                        throw nsee;
                    }
                }

                if (p !is null && (getTestOnBorrow() || isCreated && getTestOnCreate())) {
                    bool validate = false;
                    Throwable validationThrowable = null;

                    try {
                        validate = factory.validateObject(p);
                    } catch (Throwable t) {
                        warning(t.msg);
                        version(HUNT_DEBUG) warning(t);
                        PoolUtils.checkRethrow(t);
                        validationThrowable = t;
                    }

                    if (!validate) {
                        try {
                            destroy(p);
                            destroyedByBorrowValidationCount.increment();
                        } catch (Exception e) {
                            // Ignore - validation failure is more important
                        }

                        p = null;
                        if (isCreated) {
                            NoSuchElementException nsee = new NoSuchElementException(
                                    "Unable to validate object", validationThrowable);
                            throw nsee;
                        }
                    }
                }
            }
        }

        updateStatsBorrow(p, DateTime.currentTimeMillis() - waitTime);

        PooledObject!(T) pp = cast(PooledObject!(T))p;
        T obj = pp.getObject();
        
        return obj;
    }

    /**
     * {@inheritDoc}
     * <p>
     * If {@link #getMaxIdle() maxIdle} is set to a positive value and the
     * number of idle instances has reached this value, the returning instance
     * is destroyed.
     * </p>
     * <p>
     * If {@link #getTestOnReturn() testOnReturn} == true, the returning
     * instance is validated before being returned to the idle instance pool. In
     * this case, if validation fails, the instance is destroyed.
     * </p>
     * <p>
     * Exceptions encountered destroying objects for any reason are swallowed
     * but notified via a {@link SwallowedExceptionListener}.
     * </p>
     */
    void returnObject(T obj) {
        version(HUNT_POOL_DEBUG) {
            infof("%s, object: %s, Active: %d/%d, Waiters: %d", 
                typeid(T), obj.toString(), getNumActive(), getMaxTotal(),  getNumWaiters());
        }

        PooledObject!(T) p = allObjects.get(new IdentityWrapper!T(obj));

        if (p is null) {
            if (!isAbandonedConfig()) {
                throw new IllegalStateException(
                        "Returned object not currently part of this pool");
            }
            return; // Object was abandoned and removed
        }

        markReturningState(p);

        long activeTime = p.getActiveTimeMillis();

        if (getTestOnReturn() && !factory.validateObject(p)) {
            try {
                destroy(p);
            } catch (Exception e) {
                swallowException(e);
            }
            try {
                ensureIdle(1, false);
            } catch (Exception e) {
                swallowException(e);
            }
            updateStatsReturn(activeTime);
            return;
        }

        try {
            factory.passivateObject(p);
        } catch (Exception e1) {
            swallowException(e1);
            try {
                destroy(p);
            } catch (Exception e) {
                swallowException(e);
            }
            try {
                ensureIdle(1, false);
            } catch (Exception e) {
                swallowException(e);
            }
            updateStatsReturn(activeTime);
            return;
        }

        if (!p.deallocate()) {
            throw new IllegalStateException(
                    "Object has already been returned to this pool or is invalid");
        }

        int maxIdleSave = getMaxIdle();
        if (isClosed() || maxIdleSave > -1 && maxIdleSave <= idleObjects.size()) {
            try {
                destroy(p);
            } catch (Exception e) {
                swallowException(e);
            }
        } else {
            if (getLifo()) {
                idleObjects.addFirst(p);
            } else {
                idleObjects.addLast(p);
            }
            if (isClosed()) {
                // Pool closed while object was being added to idle objects.
                // Make sure the returned object is destroyed rather than left
                // in the idle object pool (which would effectively be a leak)
                clear();
            }
        }
        updateStatsReturn(activeTime);
        
        version(HUNT_DEBUG) {
            infof("object: %s, Total: %d, Active: %d, Idle: %d, Waiters: %d", 
                (cast(Object)obj).toString(), getMaxTotal(), getNumActive(), 
                getNumIdle(), getNumWaiters());
        }
    }

    /**
     * {@inheritDoc}
     * <p>
     * Activation of this method decrements the active count and attempts to
     * destroy the instance.
     * </p>
     *
     * @throws Exception             if an exception occurs destroying the
     *                               object
     * @throws IllegalStateException if obj does not belong to this pool
     */
    // override
    void invalidateObject(T obj){
        PooledObject!(T) p = allObjects.get(new IdentityWrapper!T(obj));
        if (p is null) {
            if (isAbandonedConfig()) {
                return;
            }
            throw new IllegalStateException(
                    "Invalidated object not currently part of this pool");
        }
        synchronized (p) {
            if (p.getState() != PooledObjectState.INVALID) {
                destroy(p);
            }
        }
        ensureIdle(1, false);
    }

    /**
     * Clears any objects sitting idle in the pool by removing them from the
     * idle instance pool and then invoking the configured
     * {@link PooledObjectFactory#destroyObject(PooledObject)} method on each
     * idle instance.
     * <p>
     * Implementation notes:
     * </p>
     * <ul>
     * <li>This method does not destroy or effect in any way instances that are
     * checked out of the pool when it is invoked.</li>
     * <li>Invoking this method does not prevent objects being returned to the
     * idle instance pool, even during its execution. Additional instances may
     * be returned while removed items are being destroyed.</li>
     * <li>Exceptions encountered destroying idle instances are swallowed
     * but notified via a {@link SwallowedExceptionListener}.</li>
     * </ul>
     */
    // override
    void clear() {
        IPooledObject p = idleObjects.poll();

        while (p !is null) {
            try {
                destroy(p);
            } catch (Exception e) {
                swallowException(e);
            }
            p = idleObjects.poll();
        }
    }

    // override
    int getNumActive() {
        return allObjects.size() - idleObjects.size();
    }

    override
    int getNumIdle() {
        return idleObjects.size();
    }

    /**
     * Closes the pool. Once the pool is closed, {@link #borrowObject()} will
     * fail with IllegalStateException, but {@link #returnObject(Object)} and
     * {@link #invalidateObject(Object)} will continue to work, with returned
     * objects destroyed on return.
     * <p>
     * Destroys idle instances in the pool by invoking {@link #clear()}.
     * </p>
     */
    override
    void close() {
        if (isClosed()) {
            return;
        }

        synchronized (closeLock) {
            if (isClosed()) {
                return;
            }

            // Stop the evictor before the pool is closed since evict() calls
            // assertOpen()
            stopEvitor();

            closed = true;
            // This clear removes any idle objects
            clear();

            // jmxUnregister();

            // Release any threads that were waiting for an object
            idleObjects.interuptTakeWaiters();
        }
    }

    /**
     * {@inheritDoc}
     * <p>
     * Successive activations of this method examine objects in sequence,
     * cycling through objects in oldest-to-youngest order.
     * </p>
     */
    override
    void evict(){
        assertOpen();

        if (idleObjects.size() > 0) {

            PooledObject!(T) underTest = null;
            EvictionPolicy evictionPolicy = getEvictionPolicy();

            synchronized (evictionLock) {
                EvictionConfig evictionConfig = new EvictionConfig(
                        getMinEvictableIdleTimeMillis(),
                        getSoftMinEvictableIdleTimeMillis(),
                        getMinIdle());

                bool testWhileIdle = getTestWhileIdle();

                for (int i = 0, m = getNumTests(); i < m; i++) {
                    if (evictionIterator is null || evictionIterator.empty()) {
                        evictionIterator = new EvictionIterator(idleObjects, getLifo());
                    }
                    
                    if (evictionIterator.empty()) {
                        // Pool exhausted, nothing to do here
                        return;
                    }

                    try {
                        underTest = cast(PooledObject!(T))evictionIterator.front();
                        evictionIterator.popFront();
                    } catch (NoSuchElementException nsee) {
                        // Object was borrowed in another thread
                        // Don't count this as an eviction test so reduce i;
                        i--;
                        evictionIterator = null;
                        continue;
                    }

                    if (!underTest.startEvictionTest()) {
                        // Object was borrowed in another thread
                        // Don't count this as an eviction test so reduce i;
                        i--;
                        continue;
                    }

                    // User provided eviction policy could throw all sorts of
                    // crazy exceptions. Protect against such an exception
                    // killing the eviction thread.
                    bool evict;
                    try {
                        if(evictionPolicy !is null) {
                            evict = evictionPolicy.evict(evictionConfig, underTest, idleObjects.size());
                        }
                    } catch (Exception t) {
                        // Slightly convoluted as SwallowedExceptionListener
                        // uses Exception rather than Throwable
                        PoolUtils.checkRethrow(t);
                        swallowException(new Exception("swallowed exception", t));
                        // Don't evict on error conditions
                        evict = false;
                    }

                    // version(HUNT_REDIS_DEBUG) tracef("evict=%s", evict);

                    if (evict) {
                        destroy(underTest);
                        destroyedByEvictorCount.increment();
                    } else {
                        if (testWhileIdle) {
                            bool active = false;
                            try {
                                factory.activateObject(underTest);
                                active = true;
                            } catch (Exception e) {
                                destroy(underTest);
                                destroyedByEvictorCount.increment();
                            }
                            if (active) {
                                if (!factory.validateObject(underTest)) {
                                    destroy(underTest);
                                    destroyedByEvictorCount.increment();
                                } else {
                                    try {
                                        factory.passivateObject(underTest);
                                    } catch (Exception e) {
                                        destroy(underTest);
                                        destroyedByEvictorCount.increment();
                                    }
                                }
                            }
                        }
                        if (!underTest.endEvictionTest(idleObjects)) {
                            // TODO - May need to add code here once additional
                            // states are used
                        }
                    }

                    // version(HUNT_REDIS_DEBUG) tracef("destroyedByEvictorCount = %d", destroyedByEvictorCount)                    ;
                }
            }
        }
        AbandonedConfig ac = this.abandonedConfig;
        if (ac !is null && ac.getRemoveAbandonedOnMaintenance()) {
            removeAbandoned(ac);
        }
    }

    /**
     * Tries to ensure that {@link #getMinIdle()} idle instances are available
     * in the pool.
     *
     * @throws Exception If the associated factoryexception
     */
    void preparePool(){
        if (getMinIdle() < 1) {
            return;
        }
        ensureMinIdle();
    }

    /**
     * Attempts to create a new wrapped pooled object.
     * <p>
     * If there are {@link #getMaxTotal()} objects already in circulation
     * or in process of being created, this method returns null.
     * </p>
     *
     * @return The new wrapped pooled object
     *
     * @throws Exception if the object factory's {@code makeObject} fails
     */
    private PooledObject!(T) create() {
        int localMaxTotal = getMaxTotal();
        // This simplifies the code later in this method
        if (localMaxTotal < 0) {
            localMaxTotal = int.max;
        }

        long localStartTimeMillis = DateTime.currentTimeMillis();
        long localMaxWaitTimeMillis = max(getMaxWaitMillis(), 0);

        SimpleObjectLock objectLock = new SimpleObjectLock();

        // Flag that indicates if create should:
        // - TRUE:  call the factory to create an object
        // - FALSE: return null
        // - null:  loop and re-test the condition that determines whether to
        //          call the factory
        Boolean isCreated = null;
        while (isCreated is null) {
            synchronized (makeObjectCountLock) {
                long newCreateCount = createCount.increment();
                if (newCreateCount > localMaxTotal) {
                    // The pool is currently at capacity or in the process of
                    // making enough new objects to take it to capacity.
                    createCount.decrement();
                    if (makeObjectCount == 0) {
                        // There are no makeObject() calls in progress so the
                        // pool is at capacity. Do not attempt to create a new
                        // object. Return and wait for an object to be returned
                        isCreated = Boolean.FALSE;
                    } else {
                        // There are makeObject() calls in progress that might
                        // bring the pool to capacity. Those calls might also
                        // fail so wait until they complete and then re-test if
                        // the pool is at capacity or not.
                        objectLock.wait(localMaxWaitTimeMillis.msecs);
                    }
                } else {
                    // The pool is not at capacity. Create a new object.
                    makeObjectCount++;
                    isCreated = Boolean.TRUE;
                }
            }

            // Do not block more if maxWaitTimeMillis is set.
            if (isCreated is null &&
                (localMaxWaitTimeMillis > 0 &&
                 DateTime.currentTimeMillis() - localStartTimeMillis >= localMaxWaitTimeMillis)) {
                isCreated = Boolean.FALSE;
            }
        }

        if (!isCreated.booleanValue()) {
            return null;
        }

        PooledObject!(T) p;
        try {
            p = cast(PooledObject!(T))factory.makeObject();
        } catch (Throwable e) {
            createCount.decrement();
            throw e;
        } finally {
            // FIXME: Needing refactor or cleanup -@Administrator at 2020-06-18T10:20:26+08:00
            // Failed to build with LDC. Is it a bug or an error?
            synchronized (makeObjectCountLock) {
                makeObjectCount--;
            }
            objectLock.notifyAll();
        }

        AbandonedConfig ac = this.abandonedConfig;
        if (ac !is null && ac.getLogAbandoned()) {
            p.setLogAbandoned(true);
            // TODO: in 3.0, this can use the method defined on PooledObject
            auto dpo = cast(DefaultPooledObject!(T)) p;
            if (dpo !is null) {
                dpo.setRequireFullStackTrace(ac.getRequireFullStackTrace());
            }
        }

        createdCount.increment();
        allObjects.put(new IdentityWrapper!T(p.getObject()), p);
        return p;
    }

    /**
     * Destroys a wrapped pooled object.
     *
     * @param toDestroy The wrapped pooled object to destroy
     *
     * @throws Exception If the factory fails to destroy the pooled object
     *                   cleanly
     */
    private void destroy(IPooledObject toDestroy){
        toDestroy.invalidate();
        idleObjects.remove(toDestroy);
        
        auto pooledObj = cast(PooledObject!(T))toDestroy;
        T obj = pooledObj.getObject();

        allObjects.remove(new IdentityWrapper!T(obj));
        try {
            factory.destroyObject(toDestroy);
        } finally {
            destroyedCount.increment();
            createCount.decrement();
        }

        if (idleObjects.isEmpty() && idleObjects.hasTakeWaiters()) {
            // POOL-356.
            // In case there are already threads waiting on something in the pool
            // (e.g. idleObjects.takeFirst(); then we need to provide them a fresh instance.
            // Otherwise they will be stuck forever (or until timeout)
            PooledObject!(T) freshPooled = create();
            idleObjects.put(freshPooled);
        }
    }

    override
    void ensureMinIdle(){
        ensureIdle(getMinIdle(), true);
    }

    /**
     * Tries to ensure that {@code idleCount} idle instances exist in the pool.
     * <p>
     * Creates and adds idle instances until either {@link #getNumIdle()} reaches {@code idleCount}
     * or the total number of objects (idle, checked out, or being created) reaches
     * {@link #getMaxTotal()}. If {@code always} is false, no instances are created unless
     * there are threads waiting to check out instances from the pool.
     * </p>
     *
     * @param idleCount the number of idle instances desired
     * @param always true means create instances even if the pool has no threads waiting
     * @throws Exception if the factory's makeObject throws
     */
    private void ensureIdle(int idleCount, bool always){
        if (idleCount < 1 || isClosed() || (!always && !idleObjects.hasTakeWaiters())) {
            return;
        }

        while (idleObjects.size() < idleCount) {
            PooledObject!(T) p = create();
            if (p is null) {
                // Can't create objects, no reason to think another call to
                // create will work. Give up.
                break;
            }
            if (getLifo()) {
                idleObjects.addFirst(p);
            } else {
                idleObjects.addLast(p);
            }
        }
        if (isClosed()) {
            // Pool closed while object was being added to idle objects.
            // Make sure the returned object is destroyed rather than left
            // in the idle object pool (which would effectively be a leak)
            clear();
        }
    }

    /**
     * Creates an object, and place it into the pool. addObject() is useful for
     * "pre-loading" a pool with idle objects.
     * <p>
     * If there is no capacity available to add to the pool, this is a no-op
     * (no exception, no impact to the pool). </p>
     */
    // override
    void addObject(){
        assertOpen();
        if (factory is null) {
            throw new IllegalStateException("Cannot add objects without a factory.");
        }
        PooledObject!(T) p = create();
        addIdleObject(p);
    }

    /**
     * Adds the provided wrapped pooled object to the set of idle objects for
     * this pool. The object must already be part of the pool.  If {@code p}
     * is null, this is a no-op (no exception, but no impact on the pool).
     *
     * @param p The object to make idle
     *
     * @throws Exception If the factory fails to passivate the object
     */
    private void addIdleObject(PooledObject!(T) p){
        if (p !is null) {
            factory.passivateObject(p);
            if (getLifo()) {
                idleObjects.addFirst(p);
            } else {
                idleObjects.addLast(p);
            }
        }
    }

    /**
     * Calculates the number of objects to test in a run of the idle object
     * evictor.
     *
     * @return The number of objects to test for validity
     */
    private int getNumTests() {
        int numTestsPerEvictionRun = getNumTestsPerEvictionRun();
        if (numTestsPerEvictionRun >= 0) {
            return min(numTestsPerEvictionRun, idleObjects.size());
        }
        return cast(int) (ceil(idleObjects.size() /
                abs(cast(float) numTestsPerEvictionRun)));
    }

    /**
     * Recovers abandoned objects which have been checked out but
     * not used since longer than the removeAbandonedTimeout.
     *
     * @param ac The configuration to use to identify abandoned objects
     */
    private void removeAbandoned(AbandonedConfig ac) {
        // Generate a list of abandoned objects to remove
        long now = DateTime.currentTimeMillis();
        long timeout = now - (ac.getRemoveAbandonedTimeout() * 1000L);
        ArrayList!(PooledObject!(T)) toRemove = new ArrayList!(PooledObject!(T))();

        foreach(PooledObject!(T) pooledObject; allObjects.byValue()) {
            synchronized (pooledObject) {
                if (pooledObject.getState() == PooledObjectState.ALLOCATED &&
                        pooledObject.getLastUsedTime() <= timeout) {
                    pooledObject.markAbandoned();
                    toRemove.add(pooledObject);
                }
            }
        }

        // Now remove the abandoned objects
        foreach(PooledObject!(T) pooledObject; toRemove) {
            if (ac.getLogAbandoned()) {
                // pooledObject.printStackTrace(ac.getLogWriter());
                warning("running here");
            }
            try {
                invalidateObject(pooledObject.getObject());
            } catch (Exception e) {
                // e.printStackTrace();
                warning(e);
            }
        }
    }


    //--- Usage tracking support -----------------------------------------------

    // override
    void use(T pooledObject) {
        AbandonedConfig ac = this.abandonedConfig;
        if (ac !is null && ac.getUseUsageTracking()) {
            PooledObject!(T) wrapper = allObjects.get(new IdentityWrapper!T(pooledObject));
            wrapper.use();
        }
    }


    //--- JMX support ----------------------------------------------------------

    private string factoryType = null;

    /**
     * Returns an estimate of the number of threads currently blocked waiting for
     * an object from the pool. This is intended for monitoring only, not for
     * synchronization control.
     *
     * @return The estimate of the number of threads currently blocked waiting
     *         for an object from the pool
     */
    // override
    int getNumWaiters() {
        // TODO: Tasks pending completion -@zhangxueping at 2020-03-31T16:01:28+08:00
        // to check this
        if (getBlockWhenExhausted()) {
            return idleObjects.getTakeQueueLength();
        }
        return 0;
    }

    /**
     * Returns the type - including the specific type rather than the generic -
     * of the factory.
     *
     * @return A string representation of the factory type
     */
    // override
    string getFactoryType() {
        // Not thread safe. Accept that there may be multiple evaluations.
        if (factoryType is null) {
            StringBuilder result = new StringBuilder();
            result.append(typeid(factory).name);
            result.append('<');
            implementationMissing(false);
            // Class<?> pooledObjectType =
            //         PoolImplUtils.getFactoryType(factory.getClass());
            // result.append(pooledObjectType.getName());
            result.append('>');
            factoryType = result.toString();
        }
        return factoryType;
    }

    /**
     * Provides information on all the objects in the pool, both idle (waiting
     * to be borrowed) and active (currently borrowed).
     * <p>
     * Note: This is named listAllObjects so it is presented as an operation via
     * JMX. That means it won't be invoked unless the explicitly requested
     * whereas all attributes will be automatically requested when viewing the
     * attributes for an object in a tool like JConsole.
     * </p>
     *
     * @return Information grouped on all the objects in the pool
     */
    // override
    Set!(DefaultPooledObjectInfo) listAllObjects() {
        Set!(DefaultPooledObjectInfo) result =
                new HashSet!(DefaultPooledObjectInfo)(allObjects.size());
        foreach (PooledObject!(T) p ; allObjects.byValue()) {
            result.add(new DefaultPooledObjectInfo(p));
        }
        return result;
    }

    // --- configuration attributes --------------------------------------------

    private int maxIdle = GenericObjectPoolConfig.DEFAULT_MAX_IDLE;
    private int minIdle = GenericObjectPoolConfig.DEFAULT_MIN_IDLE;
    private PooledObjectFactory!(T) factory;


    // --- internal attributes -------------------------------------------------

    /*
     * All of the objects currently associated with this pool in any state. It
     * excludes objects that have been destroyed. The size of
     * {@link #allObjects} will always be less than or equal to {@link
     * #_maxActive}. Map keys are pooled objects, values are the PooledObject
     * wrappers used internally by the pool.
     */
    private Map!(IdentityWrapper!(T), PooledObject!(T)) allObjects; 
        // new ConcurrentHashMap<>();
    /*
     * The combined count of the currently created objects and those in the
     * process of being created. Under load, it may exceed {@link #_maxActive}
     * if multiple threads try and create a new object at the same time but
     * {@link #create()} will ensure that there are never more than
     * {@link #_maxActive} objects created at any one time.
     */
    private shared long createCount = 0; // new AtomicLong(0);
    private long makeObjectCount = 0;
    private Object makeObjectCountLock; // = new Object();
    private LinkedBlockingDeque!(IPooledObject) idleObjects;

    // JMX specific attributes
    private enum string ONAME_BASE = "hunt.pool:type=GenericObjectPool,name=";

    // Additional configuration properties for abandoned object tracking
    private AbandonedConfig abandonedConfig = null;

    override
    protected void toStringAppendFields(StringBuilder builder) {
        super.toStringAppendFields(builder);
        builder.append(", factoryType=");
        builder.append(factoryType);
        builder.append(", maxIdle=");
        builder.append(maxIdle);
        builder.append(", minIdle=");
        builder.append(minIdle);
        builder.append(", factory=");
        builder.append((cast(Object)factory).toString());
        builder.append(", allObjects=");
        builder.append(allObjects.toString());
        builder.append(", createCount=");
        builder.append(createCount);
        builder.append(", idleObjects=");
        builder.append(idleObjects.toString());
        builder.append(", abandonedConfig=");
        builder.append(abandonedConfig);
    }

}